Parámetros tooltips

[jmartial]

Hola,

Pues eso, que me gustaría usar los tooltips ballon, pero no sé los parámetros del array ctooltips, o como se define un tooltip con título negrita, icono, mensaje, etc.

¿ Donde puedo mirar un ejemplo completo?

[FranciscoA]

Hola.
En mi version, estos son los parametros:
// { cToolTipText, [cHeader, [nIcon]], [nForeColor], [nBackColor] }. If the tooltip is specified as a codeblock, it can evaluate to a character value or an array.

Y aquí un ejemplo:
REDEFINE CHECKBOX oCKBOX VAR lCKBOX ID 123 OF oDlg
oCkBox:cToolTip:={"Utilicelo unicamente para el montaje inicial del inventario."+CRLF+CRLF+;
"Una vez iniciadas las operaciones de Compra-Venta, debe utilizar Entradas o Salidas. ","RECOMENDACION "}

Saludos.

[jmartial]

Muchas Gracias,

Pero y el icono? Como se pone y como se ponen los estandars de windows?

[Antonio Linares]

Joaquín,

En vez de usar <oControl>:cTooltip = "texto" puedes hacer:

<oControl>:aTooltip = { cTexto, cTitulo, nClrTexto, nClrFondo }

Otra alternativa es una los SuperTooltips de FWH:

Revisa FWH/samples/c5toolti.prg

[jmartial]

Antonio,

Quisiera usar los nativos de windows, pero y el icono. ¿Cómo lo asigno los estandars de windows o uno de los míos?

[hmpaquito]

http://forums.fivetechsupport.com/viewt ... t=0#p15939

[albeiroval]

Buen dia,

Alguien ha usado los SuperTooltips de FWH (c5tooltip) con un control GET ?
Podrian mostrar un ejemplo ?

Saludos,

[cnavarro]

Hola, prueba el siguiente ejemplo

Code: Select all

// This sample shows how to easily implement 'C5 Tool-tips' in FiveWin!

#include "FiveWin.ch"

static oWnd

//----------------------------------------------------------------------------//

function Main()

   local oBar, oBtn, oGet1, oGet2
   local cVar1 := Space( 15 )
   local cVar2 := Space( 25 )
   SetResDebug( .T. )

   DEFINE WINDOW oWnd TITLE "ToolTips in FiveWin!"

   DEFINE BUTTONBAR oBar 3D SIZE 33, 33 OF oWnd

   DEFINE BUTTON OF oBar ACTION MsgInfo( "One" )   TOOLTIP "This is a long tooltip"
   DEFINE BUTTON OF oBar ACTION MsgInfo( "Two" )   TOOLTIP "Two"
   DEFINE BUTTON OF oBar ACTION MsgInfo( "Three" ) TOOLTIP "Three"
   DEFINE BUTTON OF oBar ACTION MsgInfo( "Four" )  TOOLTIP "Four"

   @ 4,1 GET oGet1 VAR cVar1 OF oWnd PICTURE '@!' 
   oGet1:cToolTip = { || HazC5ToolTip( oGet1 ) } //"Here it is!"

   @ 4,60 GET oGet2 VAR cVar2 OF oWnd PICTURE '@!' 
   oGet2:cToolTip = { || HazC5ToolTip( oGet2 ) } //"Here it is!"

   @ 20, 8 BUTTON oBtn PROMPT "Where is my tooltip?" SIZE 180, 28 OF oWnd ;
      ACTION MsgInfo( "Oh! Thanks!" )

   // Manipulate directly the cToolTip DATA of other controls than ButtonBitmaps
   oBtn:cToolTip = { || HazC5ToolTip( oBtn ) } //"Here it is!"

   SET MESSAGE OF oWnd ;
     TO "FiveWin: CA-Clipper, xBase && OOPS development power" CENTER

   ACTIVATE WINDOW oWnd MAXIMIZED

   if File( "checkres.txt" )
      FErase( "checkres.txt" )
   endif
   CheckRes()

return nil

//----------------------------------------------------------------------------//

Function HazC5ToolTip( oCtrl )
Local oTip
//New( nTop, nLeft, nWidth, nHeight, oWnd, lDisenio, nClrPane, nClrPane2, nClrText, nWRadio, nHRadio ) CLASS TC5ToolTip
oTip := TC5ToolTip():New( 0,0 , 200, 150, oWnd, , CLR_HGRAY, CLR_HGRAY, CLR_BLUE, 0 , 0 )

oTip:nTimer                    := -1 //15000
oTip:lLineHeader           := .T.
oTip:cHeader                 := "Header"
oTip:cBmpHeader         := "..\bitmaps\16edit.bmp"

oTip:cHeader2                := "Header 2"

oTip:lLineFoot               := .T.
oTip:cFoot                     := "Footer"
oTip:cBmpFoot             := "..\bitmaps\16object.bmp"

oTip:lSplitHdr                := .T.
oTip:lLeft                       := .T.
oTip:cBmpLeft               := "..\bitmaps\16code.bmp"

oTip:lRightAlignBody  := .T.
oTip:cBody                   := "En un lugar de la Mancha de cuyo nombre no quiero acordarme"  //Memoread( "tooltip.prg") 

oTip:lBtnClose              := .F.   //.T.
oTip:lBorder                 := .F.

//oTip:lBalloon               := .T.

oCtrl:oToolTip      := oTip
Return oTip

//----------------------------------------------------------------------------//
 

Pero para que te funcione, has de modificar el Metodo MouseMove de la clase TGet

Code: Select all

//---------------------------------------------------------------------------//

METHOD MouseMove( nRow, nCol, nKeyFlags ) CLASS TGet

   if ::lDrag
      return ::Super:MouseMove( nRow, nCol, nKeyFlags )
   else
      ::oWnd:SetMsg( ::cMsg )        // Many thanks to HMP
      if ::oCursor != nil
         SetCursor( ::oCursor:hCursor )
      else
         CursorIBeam()
      endif
      ::CheckToolTip( nRow, nCol )                           // Modify

      if ::bMMoved != nil
         return Eval( ::bMMoved, nRow, nCol, nKeyFlags )
      endif
      if ::oBtn != nil
         ::oBtn:Refresh()
      endif
      TrackMouseEvent( ::hWnd, 2 ) //TME_LEAVE )     // New
   endif

return nil      // We want standard Get behavior !!!

//---------------------------------------------------------------------------//
 

[joseluisysturiz]

Antonio,

Quisiera usar los nativos de windows, pero y el icono. ¿Cómo lo asigno los estandars de windows o uno de los míos?

Basico y nativo de FW, y lo coloque en un procedure, forma de yo usarlo...haber si te sirve, saludos...

Code: Select all

   oGet:aTooltip := { cMensaje ,; // MENSAJE
                             "SISINGE - " + oDatos:cTitSis ,; // TITULO-CABEZERA(loguito)
                             nLogo ,; // IMAGEN PARA TIPO DE MENSAJE(1-informacion/2-alerta/3-stop)
                            CLR_WHITE, CLR_HBLUE } // COLOR DEL TITULO-CABEZERA(loguito)
 

agregado a un procedure

Code: Select all

PROCEDURE mi_tooltip( oGet, cMensaje, nLogo )

   DEFAULT cMensaje := "Mensaje de Ayuda"
   DEFAULT nLogo := 1

   cMensaje := CRLF + cMensaje

   oGet:cTooltip := { cMensaje ,; // MENSAJE
                      "SISINGE - " + oDatos:cTitSis ,; // TITULO-CABEZERA(loguito)
                      nLogo ,; // IMAGEN PARA TIPO DE MENSAJE(1-informacion/2-alerta/3-stop)
                      CLR_WHITE, CLR_HBLUE } // COLOR DEL TITULO-CABEZERA(loguito)
RETURN
 

despues de definir mis objetos...

Code: Select all

   mi_tooltip( aGet[13], "Fecha de Ingreso Final" )
   mi_tooltip( aBtn[1], "Pulse para Generar el Listado" )
 

[albeiroval]

Cristobal, Jose Luis,

Los dos ejemplos funcionan bien.

Decidi aplicar el ejemplo de cristobal, era lo que queria.

Gracias a ambos.

Saludos.

[albeiroval]

Cristobal, Jose Luis,

Los dos ejemplos funcionan bien.

Decidi aplicar el ejemplo de cristobal, era lo que queria.

Gracias a ambos.

Saludos.

[karinha]

Buenas, duda:

és posible usar recursos desde un .RC ó .RES?

Code: Select all

   oTip:cBmpHeader         := "..\bitmaps\16edit.bmp"
 

Regards, saludos.