FiveTech Software tech support forums

Posted: **Mon Aug 20, 2007 3:34 pm**

Hola:
Tengo el siguiente código:

FUNCTION BuscarClientes( oParent)
   LOCAL oDlg, oBrw, oBusqueda, cBusqueda, aResultado
   aResultado:=Sql("SELECT rut,nombre,ciudad,email FROM BASEDEDATOS.CLIENTES ORDER BY nombre")
   IF aResultado[1]
      IF aResultado[3]:RecordCount>0
         aResultado[3]:MoveFirst()
         DEFINE DIALOG oDlg RESOURCE "BUSCARCLIENTES"
         REDEFINE LISTBOX oBrw ;
            FIELDS Str(aResultado[3]:Fields(0):value,0), ;
                   aResultado[3]:Fields(1):value, ;
                   aResultado[3]:Fields(2):value, ;
                   aResultado[3]:Fields(3):value ;
            ID 102;
            FIELDSIZES 80, 250, 100, 250 ;
            HEADERS "R.U.T.","Razón Social","Ciudad","email" OF oDlg
         oBrw:bLogicLen := { || aResultado[3]:RecordCount }
         oBrw:bGoTop    := { || aResultado[3]:MoveFirst() }
         oBrw:bGoBottom := { || aResultado[3]:MoveLast() }
         oBrw:bSkip     := { | nSkip | Salto( aResultado[3], nSkip ) }
         oBrw:cAlias    := "ARRAY"

         REDEFINE BUTTON ID 301 OF oDlg ACTION ( oDlg:bValid:={ || .T.}, oDlg:End()) ;
            CANCEL
         ACTIVATE DIALOG oDlg CENTER VALID .F.
      ELSE
         MsgStop( "No existen Clientes en el Maestro", "Error")
      ENDIF
      aResultado[3]:Close()
      aResultado[2]:Close()
   ENDIF
RETURN NIL

Mi consulta es la siguiente:
Cómo puedo hacer para realizar una búsqueda incremental sobre el browse ya que este es un array obtenido de un objeto adodb.recordset?.
La idea es que yo escriba en el get y al presionar enter o cuando pierda el foco si detecta que hay datos en el get busque por aproximación en el browse y me posicione sobre el primer registro que coincida con la palabra encontrada. La idea es que si coloco AB se posicione sobre el primer registro que comienza con AB.
Esto lo hago sin problemas al realizar un browse directamente a un .DBF. Nunca lo he realizado en un array.

He intentado esto para poder obtener los datos seleccionados en el browse al presionar un botón o hacer doble click sobre el registro:
Code: Select all
nPos:=oBrw:nAt //==>retorna NIL
nPos:=oBrw:nRowPos //==> retorna el registro donde estoy
MsgInfo( oBrw:aArray[1,1] //hace que mi aplicación se cuelgue. No muestra ningún error. Simplemente se cuelga.

Saludos y mil gracias
David Lagos S.
Coquimbo-Chile

P.D:René, tu blog está excelente. Felicitaciones.
Adjunto una imagen

Posted: **Mon Aug 20, 2007 9:57 pm**

David,

Tendrás que buscar en los elementos del array, bien usando Left() ó At()

Posted: **Mon Aug 20, 2007 10:12 pm**

Antonio Linares wrote:David,

Tendrás que buscar en los elementos del array, bien usando Left() ó At()

Antonio, gracias por la respuesta. Con relación a cómo obtener los datos cuando presiono un botón, ya está resuelto.
Lo que tengo que hacer ahora es poder reasignar _ al browse en tiempo de ejecución y refrescar el browse.

Si no me equivoco debo modifica el oBrw:bLine, correcto?
Y si es así como recargo :bLine nuevamente?, me refiero a la forma de pasar los datos.
Me explico. Estoy realizando nuevamente una consulta SQL del tipo where nombre like 'hdhdhd%'. El nuevo resultado de la consulta con adodb.recordset la debo cargar al browse como cuando utilizo el REDEFINE LISTBOX.
Saludos
David Lagos S.
Coquimb-Chile

Posted: **Mon Aug 20, 2007 10:19 pm**

David,

bLine es un codeblock que tiene que devolver un array, con un valor por cada columna. Lo interesante es que puede llamar a una función que realice _ que sean necesarios y devuelva el array:

oBrw:bLine = { || { <col1>, ..., <colN> } }

ó llamar a una función:

Code: Select all

oBrw:bLine = { || CalculaValores() }

function Calculavalores()

   ... calcula col1, ... colN

return { <col1>, ..., <colN> }

Posted: **Tue Aug 21, 2007 4:37 pm**

Antonio Linares wrote:David,

bLine es un codeblock que tiene que devolver un array, con un valor por cada columna. Lo interesante es que puede llamar a una función que realice _ que sean necesarios y devuelva el array:

oBrw:bLine = { || { <col1>, ..., <colN> } }

ó llamar a una función:
Code: Select all
oBrw:bLine = { || CalculaValores() }

function Calculavalores()

   ... calcula col1, ... colN

return { <col1>, ..., <colN> }

Antonio:
el bline lo estoy usando para obtener los datos a través de un eval() que funcional a las mil maravillas.
Aún sigo entrampado con el tema de la búsqueda incremental.
He intentado a realizar un oRS:Source:="nueva consulta SQL" y luego un oRS:Requery() y se cuelga mi aplicación al momento de oRS:Source.
Pensando que podía ser por tener el oBrw activo realicé oBrw:Disable() y/o oBrw:Hide() y nada.
Es lo único que me falta realizar para tener la rutina lista de búsqueda de clientes que me va a servir para cualquier búsqueda.
No puedo utilizar el nAt, aArray o AScan() ya que nAt retorna nil debido a que nunca utilizo el setarray() ya que los que paso son los datos de un objeto obtenido desde un adodb.recordset.
Alguien más que me pueda ayudar. Quizás René, ya que tu trabajas todo ADO duro y puro según contaste en un post pasado.
Gracias nuevamente.
Saludos
David Lagos S.
Coquimbo-Chile

Posted: **Tue Aug 21, 2007 7:35 pm**

A ver compañeros:
Primero que todo mil gracias a Vikthor por darme la pauta inicial por donde resolver el problema.

Cuando trabajamos con Ado _ los datos obtenidos del objeto adobdb.recorset al browse utilizando el método Fields(nº de campo):value en la clausula FIELDS. además debemos definir oBrw:cArray:="ARRAY". Si el campo retorna un número debemos pasarlo a cadena. MUY Importante esto.

Como lo que necesitaba era hacer una búsqueda incremental el paso es el siguiente:

Definimos o Redefinimos un campo GET y le agregamos lo siguiente:
/*cBusqueda es la variable definida en el GET, puede ser cualquiera*/
/*oRs es el objeto RecordSet que creamos anteriomente para obtener los datos desde nuestro servidor de base de datos*/
oGet:bLostFocus:={|| Iif( Funcion_de_Busqueda( cBusqueda, oRs), oBrw:Refresh(), NIL)}

NUNCA UTILIZAR oBrw:UpStable() ==> la aplicación se cuelga.

Code: Select all

STATIC FUNCTION Funcion_de_Busqueda( cBusqueda, oRs)
   LOCAL lBusqueda:=.F., nBookMark:=oRs:BookMark
   IF !Empty( cBusqueda)
      oRs:MoveFirst()
      oRs:Find( "nombre LIKE '"+Alltrim(cBusqueda)+"%'",,1)
      IF oRs:Eof()==.F. .AND. oRs:Bof()==.F.
         lBusqueda:=.T.
      ELSE
         oRs:BookMark:=nBookMark
         MsgStop( "No encotramos nada")
      ENDIF
   ENDIF
RETURN lBusqueda

Adjunto imágenes
1.- Mostrando el browse

2.- Si se fijan colocamos el texto: LA y nos muestra la primera coincidencia.

3.- Informamos al usuario que su búsqueda falló:

FiveTech Software tech support forums

Búsqueda incremental en wbrowse - SOLUCIONADO vean solución

Búsqueda incremental en wbrowse - SOLUCIONADO vean solución