Envio de SMS ejemplo de como se hace

[Enrrique Vertiz]

Buenas tardes

Consulto al foro si alguien tendra un ejemplo de como enviar SMS desde una aplicacion FWH.
Muchas gracias

[Sistem]

Code: Select all

// necessário a lib hbcomm.lib eh necessário um modem
// usei essa função uns 3 anos atrás com modem 3G 
// código resumido para melhor entendimento
Function SMSEnvia()
 Local nHandle, cBuffer, nChar

   cPort := "\\.\COM3"           // porta usada pelo modem 
   cTel  :="5585999998888"       // 55=Brasil  85=(estado do brasil)  999998888=telefone
   cMsg  := "messagem teste"     // messagem a enviar

   nHandle := Init_Port( cPort, 9600, 8, 0, 1, 1024 )
   If nHandle <= 0
      MsgStop("Erro comunicacao, porta: "+cPort, "Aviso!")
      Return .f.
   Endif

   OutBufClr(nHandle)
   OutChr( nHandle, "AT+CMGF=1" + Chr(13) )
   SysWait(1)
// OutChr( nHandle, "AT+CSCS=GSM" + Chr(13) )
// SysWait(2)
   OutChr( nHandle, "AT+CMGS=" + Chr(34) + cTel + Chr(34) + Chr(13) )
   SysWait(1)
   OutChr(nHandle, cMsg + Chr(26))
   SysWait(1)
   nChar   := InBufSize( nHandle )
   cBuffer := Len(cTel) + Len(cMsg)
   InChr( nHandle, nChar, @cBuffer )
   UnInt_Port( nHandle )

Return nil

[Enrrique Vertiz]

Mi estimado, no entiendo, lo que necesito es enviar un SMS desde una aplicacion FWH, de la forma que sea la mejor, creo que utilizando algun API de algun Web que brinde el servicio ??

[Sistem]

Mi estimado, no entiendo, lo que necesito es enviar un SMS desde una aplicacion FWH, de la forma que sea la mejor, creo que utilizando algun API de algun Web que brinde el servicio ??

você vai precisar de algum serviço de terceiro, não conheço serviço grátis

[leandro]

Enrique como vas?

Yo lo hago a través de una API (de pago)

Code: Select all

FUNCTION enviando_texto()

local mensaje := {=>}
local user := "myuser"
local pass := "mypassword"
local cBas64 := hb_base64encode(user+":"+pass,len(user+":"+pass))

mensaje["from"] := "empresa"
mensaje["to"] := "57123456789"
mensaje["text"] := "Ejemplo Contenido del Mensaje" //ACEPTA 160 CARACTERES
enviar := hb_jsonEncode( mensaje )

ohttp := CreateObject( "MSXML2.XMLHTTP" )
ohttp:Open( "POST" ,"http://myurl",.F.)
oHttp:SetRequestHeader("cache-control", "no-cache")
ohttp:SetRequestHeader("content-type", "application/json" )
ohttp:SetRequestHeader("authorization", "Basic "+cBas64 )
TRY
  ohttp:Send( enviar )
CATCH
    msginfo("No Se Pudo Enviar Documento JSON","Intente Nuevamente")
    return .t.
END
response:=ohttp:responseText

aHasRes := hash()
hb_jsondecode(response ,@aHasRes) //Parse JSON to hash
xBrowse(aHasRes)


RETURN NIL
 

[Enrrique Vertiz]

Saludos System

Gracias por tu respuesta, las maquinas actuales creo que ya ni traen moden, lo ideal seria por una API no se si hay gratis o si hay que pagar, pero la idea es que sea por medio de una Web.

Saludos Leandro

Gracias por tu respuesta, entiendo que tu ejemplo funcionara con cualquier API de pago que soporte JSON ?? es asi, si puedes me compartes el API que usas para ver si vale la pena para nosotros tambien contratarla ??
Gracias

[leandro]

Hola Enrique

https://colombiared.com.co/

Si contratas con ellos, lo unico que tendrias que cambiar en el código, seria el nombre de usuario y la contraseña.

Saludos