RadioButton Horizontal

[servicomver]

Hola, tengo una duda respecto asi se puede, por comando, hacer radio botton pero "Horizontales", ya que por default siempre son Verticales
mas o menos asi " Local (*) Foraneo ( ) garantia ( )", espero me haya explicado correctamente.

La otra es que al mandar un preview de la clase PRINT oPrn sale todo "amontonado" tengo que cambiar de FACTOR a 1 o 2 y luego regresarlo a 1 para que se vea detalladamente la informacion, hay alguna forma de evitar esta desagradable presentacion. ??

Gracias por el tiempo y apoyo, Saludos

[MarioG]

Te envio una contribución sobre radios horizontales, que ya no recuerdo el autor para mencionarlo, a tu privado.

Saludos

[MarioG]

Necesito una dirección de correo a donde enviartelo

saludos

[servicomver]

disculpa el tiempo que tarde en darte mi correo, lo puedes mandar a:
servicomver@hotmail.com
servicomver@yahoo.com.mx
gracias por tu atencion
salu2

[Antonio Linares]

Mario,

Puedes subirlo a http://www.hyperupload.com y poner aqui el enlace para descargarlo ? gracias.

[Manuel Valdenebro]

Necesito una dirección de correo a donde enviartelo

saludos

Mario,
Te agradecería me enviaras a mi email lebsoft@mixmail.com el fichero.

Muchas gracias y feliz año.

Manuel

[Antonio Linares]

Esta es la sintaxis que hemos implementado para crear radios individuales, pertenecientes a un radmenu:

Code: Select all

 
#xcommand @ <nRow>, <nCol> RADIOITEM [ <oRadItem> PROMPT ] <cCaption> ; 
             [ <of: OF, WINDOW, DIALOG> <oWnd> ] ; 
             [ RADIOMENU <oRadMenu> ] ; 
             [ <help:HELPID, HELP ID> <nHelpId> ] ; 
             [ <change: ON CLICK, ON CHANGE> <uChange> ] ; 
             [ COLOR <nClrFore> [,<nClrBack>] ] ; 
             [ MESSAGE <cMsg> ] ; 
             [ <update: UPDATE> ] ; 
             [ WHEN <uWhen> ] ; 
             [ SIZE <nWidth>, <nHeight> ] ; 
             [ VALID <uValid> ] ; 
             [ <lDesign: DESIGN> ] ; 
             [ <lLook3d: 3D, _3D> ] ; 
             [ <lPixel: PIXEL> ] ; 
       => ; 
          [<oRadItem> := ] TRadio():New( <nRow>, <nCol>, <cCaption>, .f., .f.,; 
            Len( <oRadMenu>:aItems ) + 1, <oWnd>, <oRadMenu>,; 
            [<nHelpId>], [<nClrFore>], [<nClrBack>], [<cMsg>], [<.update.>], [<{uWhen}>],; 
            [<nWidth>], [<nHeight>], [<{uValid}>], [<.lDesign.>], [<.lPixel.>] );; 
            AAdd( <oRadMenu>:aItems, ATail( <oWnd>:aControls ) ) 

este es un ejemplo de uso:

Code: Select all

@ 8, 2 RADIOITEM "F&our" RADIOMENU oRadMenu SIZE 80, 15 OF oWnd 

[Manuel Valdenebro]

Antonio, gracias por tu respuesta. Pero nada mas incluir en el fichero include el #xcommand (cortar y pegar) al compilar, me da el error "unknown result marker in #command.

Por otra parte, en el codigo actual, tengo una variable, ¿como podria acoplarla al ejemplo?

@ 9, 30 RADIO oRbx VAR oDbf:FORMA PROMPT "Caja", "Banco ;
OF oFol:aDialogs[2] ;
SIZE 30,12 PIXEL

Gracias y un saludo desde Málaga

Manuel

[Antonio Linares]

Manuel,

> "unknown result marker in #command.

Hay un fallo en el comando que hemos publicado, en el resultado hay que escribir [<.update.>] en vez de .lUpdate.

>
@ 9, 30 RADIO oRbx VAR oDbf:FORMA PROMPT "Caja" ;
OF oFol:aDialogs[2] ;
SIZE 30,12 PIXEL
>

@ ..., ... RADIOITEM "Banco" RADIOMENU oRbx SIZE 30, 12 OF oFol:aDialogs[2] PIXEL

[Manuel Valdenebro]

Antonio,

Ahora compila bien, pero al ejecutar da el error aItem(0).

Un saludo

Manuel

[Antonio Linares]

Manuel,

Este ejemplo compila y funciona bien. Puedes probarlo ?

Code: Select all

// Testing some radio buttons

#include "FiveWin.ch"

static oWnd

//----------------------------------------------------------------------------//

function Main()

   local nValue := 3, oRad

   SET _3DLOOK ON
   SET HELPFILE TO "Test.hlp"

   DEFINE WINDOW oWnd ;
      TITLE "Testing a Radio Buttons Menu" COLOR "N/W"

   @ 1, 1 BUTTON "&Test" SIZE 70, 20 ;
      ACTION ( MsgInfo( nValue ), oRad:aItems[ 2 ]:SetText( "&Changed!" ) )

   @ 3, 2 RADIO oRad VAR nValue ;
      ITEMS "&One", "&Two", "T&hree" _3D SIZE 150, 25 ;
      HELPID 100, 101, 102 ;
      ON CHANGE MsgBeep()

   @ 5, 25 RADIOITEM "Fo&ur" RADIOMENU oRad OF oWnd SIZE 150, 25

   ACTIVATE WINDOW oWnd

return nil

//----------------------------------------------------------------------------//

[Manuel Valdenebro]

Antonio, ahora si funciona. He utilizado el siguiente código:

// Testing some radio buttons

#include "FiveWin.ch"

static oWnd

//----------------------------------------------------------------------------//

function Main()

local nValue := 1, oRad

SET _3DLOOK ON

DEFINE WINDOW oWnd ;
TITLE "Testing a Radio Buttons Menu" COLOR "N/W"

@ 1, 1 BUTTON "&Test" SIZE 70, 20 ;
ACTION MsgInfo( nValue )

@ 3, 2 RADIO oRad VAR nValue ;
ITEMS "&Uno" _3D SIZE 150, 25 ;

@ 3, 20 RADIOITEM "&Dos" RADIOMENU oRad OF oWnd SIZE 150, 25

@ 3, 40 RADIOITEM "&Tres" RADIOMENU oRad OF oWnd SIZE 150, 25

ACTIVATE WINDOW oWnd

return nil

//----------------------------------------------------------------------------//

Un saludo y muchas gracias