Trabajando con WORD

[Blessed]

Saludos

Necesito crear documentos de Microsoft Word, sin abrir Word, Escribir datos de una factura, en el documento de word, con determinadas FONTS.
Alguna idea de como hacer algo asi.

[horacio]

Este ejemplo me parece que lo saqué del foro, fijate si te sirve

Code: Select all

#Include "FiveWin.ch"

//--------------------------//
Function Main()
LOCAL oWord, oSelection, nX, nPoint := 60
oWord := CreateObject("Word.Application") //creating Wordobject
   oWord:visible := .T.
   oWord:Documents:Add() //adding a new document
   oSelection := oWord:Selection  //getting the active selection
         With Object oSelection
            :TypeText("Now setting the tabs"+CRLF)
            WITH OBJECT :ParagraphFormat:TabStops
               :ClearAll() //clearing all existing tabs
               FOR nX := 1 TO 3
                  :Add( nPoint, 0) //adding new left tabs
                  nPoint += 60
               NEXT
            END WITH
            :TypeText("left"+CHR(9)+"2"+CHR(9)+"3"+CRLF)
            nPoint := 60
            WITH OBJECT :ParagraphFormat:TabStops
               :ClearAll() //clearing all existing tabs
               FOR nX := 1 TO 3
                  :Add( nPoint, 1) //adding new center tabs
                  nPoint += 60
               NEXT
            END WITH
            :TypeText("center"+CHR(9)+"22222"+CHR(9)+"3333"+CRLF)
           nPoint := 60
           WITH OBJECT :ParagraphFormat:TabStops
               :ClearAll() //clearing all existing tabs
               FOR nX := 1 TO 3
                  :Add( nPoint, 2) //adding new right tabs
                  nPoint += 60
               NEXT
            END WITH
            :TypeText("right"+CHR(9)+"2"+CHR(9)+"3"+CRLF)
           nPoint := 60
           WITH OBJECT :ParagraphFormat:TabStops
               :ClearAll() //clearing all existing tabs
               FOR nX := 1 TO 3
                  :Add( nPoint, 3) //adding new decimal tabs
                  nPoint += 60
               NEXT
            END WITH
            :TypeText("decimal"+CHR(9)+"2,1"+CHR(9)+"3,1"+CRLF+CRLF)

            :TypeText("Now setting fonts"+CRLF)
            WITH OBJECT :ParagraphFormat:TabStops
               :ClearAll() //clearing all existing tabs
             END WITH
             :Font:Name="Arial"
             :TypeText("Arial"+CHR(9)+"2"+CHR(9)+"3"+CRLF)
             :Font:Size=16
             :TypeText("Arial Size 16"+CHR(9)+"2"+CHR(9)+"3"+CRLF)
             :Font:Size=10
             :Font:Name="Courier"
             :TypeText("Courier Size 10"+CHR(9)+"2"+CHR(9)+"3"+CRLF)
             :Font:Bold=1
             :TypeText("Courier Bold 10"+CHR(9)+"2"+CHR(9)+"3"+CRLF)
             :Font:Bold=0
             :TypeText("Courier Normal 10"+CHR(9)+"2"+CHR(9)+"3"+CRLF)
             :Font:Italic=1
             :TypeText("Courier Italic 10"+CHR(9)+"2"+CHR(9)+"3"+CRLF)
             :Font:Italic=0
             :TypeText("Courier Normal 10"+CHR(9)+"2"+CHR(9)+"3"+CRLF)

         end with

Return nil

 

Saludos

[Blessed]

Horacio, muchas gracias
Es justamente lo que buscaba; Funciona muy bien

Saludos

[juanjogascem]

Hola, una pregunta:

Como haceis para abrir el documento word desde la aplicacion?

Juanjo

[sysctrl2]

oWord:visible := .T.

[juanjogascem]

Perfecto, pero donde puedo encontrar documentacion al respecto, porque necesitaria justificar texto e incluir un logotipo.

Juanjo

[sysctrl2]

con el permiso de su autor,
http://forums.fivetechsupport.com/viewt ... =17&t=6849
tword te servira de mucho.
saludos..

[juanjogascem]

Gracias Cesar.

Un saludo

[juanjogascem]

hola de nuevo,
al intentar compilar la clase TWord con la aplicacion me da el siguiente error:

Error: Unrresolved external "_hb_Fun_oleuniunitialize. reference from ... tword.obj

¿Alguna solucion?


Un saludo
Juanjo