Scripts para Harbour y FWH !!!

[Antonio Linares]

We have modified DEFINE MSGBAR ... to accept 2007 clause too:

Code: Select all

#xcommand DEFINE <msg: MESSAGE, MESSAGE BAR, MSGBAR> [<oMsg>] ;
             [ OF <oWnd> ] ;
             [ <prm: PROMPT, TITLE> <cMsg> ] ;
             [ <center: CENTER, CENTERED> ] ;
             [ <clock: CLOCK, TIME> ] ;
             [ <date: DATE> ] ;
             [ <kbd: KEYBOARD> ] ;
             [ FONT <oFont> ] ;
             [ <color: COLOR, COLORS> <nClrFore> [,<nClrBack> ] ] ;
             [ <inset: NO INSET, NOINSET> ] ;
             [ <l2007: 2007, _2007> ] ;             
      => ;
         [<oMsg>:=] <oWnd>:oMsgBar := TMsgBar():New( <oWnd>, <cMsg>, <.center.>,;
                                      <.clock.>, <.date.>, <.kbd.>,;
                                      <nClrFore>, <nClrBack>, <oFont>,;
                                      [!<.inset.>], [<.l2007.>] )

[Simon]

Todavia no doy con el problema, es compilando el script, habia comentado la linea del msgbar.

No tienen idea del porque me da ese error.

[Antonio Linares]

Simón,

Comprueba que tengas puestos los paths bien aqui:

Code: Select all

   oHrb = HB_CompileFromBuf( Scripts->Code, "-n", "-Ic:\fwh\include", "-Ic:\harbour\include" )

[Simon]

Si esas son las carpetas, se me olvido mencionar que tengo instalado windows 7 de 64 bits, tengo vmware instalado estoy haciendo una maquina con windows xp de 32 pruebo y te aviso.

[Simon]

Reescribi scripts.prg, y ahora funciona perfectamente, esta buenimiso, se pueden usar funciones, recursos, variables que esten en nuestro exe.

Antonio no hay manera de hacer esto mismo sin necesidad de tener instalado el harbour ?

[Antonio Linares]

Simón,

No necesitas tener instalado Harbour!

El compilador de Harbour está dentro de nuestros EXEs

Lo que si necesitas son los ficheros de cabecera (.CH)

[Simon]

ya he probado, y no necesito tampoco los de fivewin (a menos que necesite usar fivewin como xbase) , ahora necesito todos los archivos de cabecera de harbour o solo algunos ?

[Antonio Linares]

Solo para los comandos que uses desde tu script, por ejemplo: USE ...

[Simon]

Antonio en caso de existir un error en el script, puedo capturar la linea del error con un try-catch ?

[Antonio Linares]

Simón,

Esta es una forma de hacerlo:

Code: Select all

function Execute()

   local oHrb, cResult, bOldError

   FReOpen_Stderr( "comp.log", "w" )
   oHrb = HB_CompileFromBuf( Scripts->Code, "-n", "-Ic:\fwh\include", "-Ic:\harbour\include" )
   oResult:SetText( If( Empty( cResult := MemoRead( "comp.log" ) ), "ok", cResult ) )
   
   if ! Empty( oHrb )
      BEGIN SEQUENCE
      bOldError = ErrorBlock( { | o | DoBreak( o ) } )
      hb_HrbRun( oHrb )
      END SEQUENCE
      ErrorBlock( bOldError )
   endif   

return nil

static function DoBreak( oError )

   local cInfo := oError:operation, n

   if ValType( oError:Args ) == "A"
      cInfo += "   Args:" + CRLF
      for n = 1 to Len( oError:Args )
         MsgInfo( oError:Args[ n ] )
         cInfo += "[" + Str( n, 4 ) + "] = " + ValType( oError:Args[ n ] ) + ;
                   "   " + cValToChar( oError:Args[ n ] ) + CRLF
      next
   endif

   MsgStop( oError:Description + CRLF + cInfo,;
            "Script error at line: " + Str( ProcLine( 4 ) ) )

   BREAK

return nil
 

[Simon]

Claro begin/secuence, yo estaba usando try/catch.

Gracias Antonio, sigo probando.

[Simon]

Antonio esta linea

Code: Select all

MsgStop( oError:Description + CRLF + cInfo,;
            "Script error at line: " + Str( ProcLine( 4 ) ) )
 

devuelve el numero de linea pero del programa que lo esta ejecutando y no la linea del script, estuve probando y me funciono cambiando procline( 4 ) por procline( 2 ).

[Antonio Linares]

Simón,

gracias!

[diegopolverelli]

se pueden agregar scripts que hagan uso de bases de datos???
puedo usar variables del programa principal???
por ej, quiero que lo que se ejecute, en lugar de un msginfo sea un:
use c:\base1
count to cantidad
? str(cantidad)


¿se puede? Gracias...!!!

[Antonio Linares]

Diego,

Claro que si !