FiveTech Software tech support forums

Posted: **Tue Sep 24, 2019 2:49 pm**

amigos necesito manejar la fecha en un combobox, ahora yo cargo un combobox de una tabla asi

cViajee=xServer:Query("SELECT fecha_salida FROM viajes_generados WHERE fecha_salida>='"+Dtos(Date())+"' GROUP BY fecha_salida ORDER BY fecha_Salida")
cViajee:Gotop()
Do While !cViajee:Eof()
AADD(aFecha,Dtoc(cViajee:fecha_salida))
cViajee:Skip()
EndDo
cViajee:End()

Todo bien. pero la muestra asi
24-09-2019
25-09-2019
26-09-2019
y asi sucesivamente, pero esta bien ...
lo que pasa que ahora la quiero asi:
Martes, 24 de Septiembre de 2019
Miercoles, 25 de septiembre de 2019
Jueves, 26 de septiembre de 2019
o tambien puede ser:

Martes, 24-09-2019
Miercoles, 25-09-2019
Jueves, 26-09-2019
.
.
.
.eso quiero que me muestre el dia y el mes
saludos

Posted: **Tue Sep 24, 2019 4:55 pm**

Code: Select all

cViajee := xServer:Query("SELECT fecha_salida FROM viajes_generados WHERE fecha_salida>=" + Var2Str( Date() ) + " GROUP BY fecha_salida ORDER BY fecha_Salida")
cViajee:Gotop()
Do While !cViajee:Eof()
  AADD( aFecha, MyDate( cViajee:fecha_salida) )
cViajee:Skip()
EndDo
cViajee:End()

Code: Select all

function MyDate( d )
 local cD := ""
 if !empty( d )
  cD := CDoW( d ) + "," + hb_ntos( day( d ) ) + " de " + CMonth( d ) + " de " + hb_ntos( year( d ) )
 endif
return cD


FUNCTION Var2Str( xValue )
   LOCAL cValue := "''"
   LOCAL cType  := ValType( xValue )

   DO CASE
   CASE cType=="C"
      cValue := "'" + AllTrim( xValue ) + "'"
   CASE cType=="M"
      cValue := "'" + xValue + "'"
   CASE cType=="N"
      cValue := hb_NtoS( xValue )
   CASE cType=="L"
      cValue := IIf( xValue, '1', '0' )
   CASE cType=="D"
      cValue := "'" + Transform( DToS( xValue ), "@R 9999-99-99" ) + "'"
   CASE cType=="T"
      cValue := "'" + Transform( TToS( xValue ), "@R 9999-99-99 99:99:99" ) + "'"
   ENDCASE

RETURN cValue

FiveTech Software tech support forums

Fecha en un Combobox

Fecha en un Combobox

Re: Fecha en un Combobox