FiveTech Software tech support forums

Code: Select all

#include "Fivewin.ch"


function Main()

   local oDlg_GenAut, oBtnAnade, oBrowPed,;
         aValues := { { "One", "Two", "Three" }, { "Four", "Five", "Six" } },;
         oGetCodArt, oGetUdsPed, cCod := Space( 14 ), nCan := 0, nRGBColor := nRGB( 0,255,255 )
         
   SetGetColorFocus( nRGBColor )

   DEFINE DIALOG oDlg_GenAut RESOURCE "DLG_GENAUT"

   REDEFINE BUTTON oBtnAnade ID 4050 OF oDlg_GenAut UPDATE ACTION ( oGetCodArt:Enable(), oGetUdsPed:Enable(), oGetCodArt:SetFocus() )
   
   REDEFINE LISTBOX oBrowPed;
      FIELDS aValues[ oBrowPed:nAt, 1 ], aValues[ oBrowPed:nAt, 2 ], aValues[ oBrowPed:nAt, 3 ];
       ID 90 OF oDlg_GenAut UPDATE
      oBrowPed:SetArray( aValues )    
      
   REDEFINE GET oGetCodArt VAR cCod ID 100 OF oDlg_GenAut PICTURE '@!S12' UPDATE;
            VALID ( MsgInfo( "Ejecutando Valid" ), .t. )

   REDEFINE GET oGetUdsPed VAR nCan ID 140 OF oDlg_GenAut PICTURE '@EZ 999,999' UPDATE;
            VALID ( oGetCodArt:Disable(), oGetUdsPed:Disable(), oBrowPed:Refresh(), .t. )

   ACTIVATE DIALOG oDlg_GenAut CENTERED ON INIT ( oGetCodArt:Disable(), oGetUdsPed:Disable() )

   DbCloseAll()

return nil

Code: Select all

#include <windows.h>
#include <commctrl.h>
#include <richedit.h>

LANGUAGE LANG_ENGLISH,SUBLANG_ENGLISH_US

DLG_GENAUT DIALOG DISCARDABLE 65, 47, 231, 193
STYLE WS_POPUP|DS_MODALFRAME|WS_CAPTION|WS_SYSMENU|WS_VISIBLE
CAPTION "Prueba"
FONT 8, "MS Sans Serif"
{
  CONTROL "", 90, "TWBrowse", WS_DISABLED|WS_TABSTOP|0x00b00000, 4, 4, 224, 149
  CONTROL "Código:", -1, "Static", WS_GROUP, 4, 164, 28, 9
  CONTROL "", 100, "Edit", WS_BORDER|WS_TABSTOP, 36, 160, 63, 12
  CONTROL "Cantidad:", -1, "Static", WS_GROUP, 4, 180, 32, 8
  CONTROL "", 140, "Edit", WS_BORDER|WS_TABSTOP, 36, 176, 38, 12
  CONTROL "Añadir", 4050, "Button", WS_TABSTOP, 120, 160, 52, 12
}

 

Code: Select all

//////////////////////////////////////////////////////////////////
FUNCTION ForceFocus(oJump)
Local oFocus:= oWndFromHwnd(GetFocus())  // Indocumentada (Window.Prg)
Local bValid, bWhen
*
IF If(oFocus != NIL, oFocus:hWnd != oJump:hWnd, .t.)  // No sea el mismo objeto el
                                                      // actual y el que se salta
   *
   IF oFocus != NIL
      bWhen:=         oFocus:bWhen
      bValid:=        oFocus:bValid
      oFocus:bWhen:=  {|| .f. }
      oFocus:bValid:= {|| .t.}  // Este no se si necesario, pero por si acaso.
   ENDIF
   *
   *
   IF __ObjHasMethod(oJump, "FORWHEN")  // en _ oJump es de la clase TWindow
      oJump:ForWhen()
   ENDIF
   *
   *
   oJump:SetFocus()
   *
   IF oFocus != NIL
      IF !(oFocus:ClassName() $ "TWINDOW,TDIALOG")
         IF bWhen == NIL
            // Necesarisimo, pq si es NIL, entonces en el ForWhen()
            // no se entera pq en window en aEval() se lo salta
            // si bWhen es NIL y entonces no lo Enable()
            oFocus:bWhen:=  {|| .t. }
            *
         ELSE
            oFocus:bWhen := bWhen
         ENDIF

         // Solo si deriva de TControl
         oFocus:ForWhen()
      ENDIF
      *
      oFocus:bWhen := bWhen
      oFocus:bValid:= bValid
   ENDIF

   *
ENDIF
*
RETURN NIL
*
 

Code: Select all

   REDEFINE BUTTON oBtnAnade ID 4050 OF oDlg_GenAut UPDATE ACTION ( oGetCodArt:Enable(), oGetUdsPed:Enable(), ForceFocus( oGetCodArt ) )
 

Code: Select all

#Translate @ <nRow>, <nCol> MIGET <oGet> ;
                  [PREVALID <bPreValid>] ;                         // Action PreValid
                  [VALID <bValid> ;                                    // Exclusivamente condicion de validacion: luego es facil preguntar solo por las condiciones de validacion de todos los gets
                 [ POSTVALID <bPostValid>]                        // Action PostValid
                 [JUMPTO <oJump> ];
                 => ;
                @ <nRow>, <nCol> GET <oGet> ;
                       VALID (;
                                   If(<.bPreValid.>, Eval(<bPreValid>), NIL),;
                                   l:= Eval(<bValid>),;
                                   If(<.bPostValid.>, Eval(<bPostValid>), NIL),;
                                   If(l .AND. <.oJump.>, ForceFocus(<oJump>), NIL);
                                  )
 

Code: Select all

              ::PostMsg( FM_CLICK )    // fire the button's action
 

Code: Select all

            ::PostMsg( WM_LBUTTONDOWN, 1, 1 )
            ::PostMsg( WM_LBUTTONUP, 1, 1 )
 

Code: Select all

oBtnAnade:nDlgCode = DLGC_WANTALLKEYS

Code: Select all

#define WM_NEXTDLGCTL                   0x0028
 

Code: Select all

REDEFINE BUTTON oBtnAnade ID 4050 OF oDlg_GenAut UPDATE ACTION ( oGetCodArt:Enable(), oGetUdsPed:Enable(), oGetCodArt:SetFocus() )
 

Code: Select all

REDEFINE BUTTON oBtnAnade ID 4050 OF oDlg_GenAut UPDATE ACTION ( oGetCodArt:Enable(), oGetUdsPed:Enable(), oDlg_GenAut:PostMsg( WM_NEXTDLGCTL, oGetCodArt:hWnd, 1 ) )
 

Code: Select all

...
EXTEND CLASS TDIALOG    WITH METHOD MySetFocus
...

FUNCTION MySetFocus( xData )
   LOCAL Self := HB_QSelf()

   DO CASE
   CASE ValType( xData )=="O"
      ::PostMsg( WM_NEXTDLGCTL, xData:hWnd, 1 )
   CASE ValType( xData )=="N"
      IF Len( ::aControls ) >= xData
         ::PostMsg( WM_NEXTDLGCTL, ::aControls[ xData ]:hWnd, 1 )
      ENDIF
   ENDCASE

RETURN NIL
...
 

Code: Select all

PROCEDURE FlujoRuta_SeleccionarRuta()
   LOCAL oDBSearch := TDBSearch():new( "Lista de ruta de cobro" )

   WITH OBJECT oDBSearch
      :cAlias   := "RUTA"
      :bFields  := { || { RUTA->NUM_RUTA, RUTA->NOMBRE } }
      :aHeaders := { "Número", "Nombre de gestor" }
      :aJustify := { 2, 0 }
      :aOrders  := { { "NUM_RUTA" }, { "Numero de ruta" } }
      :cCurOrd  := "NUM_RUTA"
      :nCurOrd  := 1
      IF :open()
         cNumRuta := RUTA->NUM_RUTA
         cNomRuta := RUTA->NOMBRE
         cNomCobr := COBR->NOMBRE
         oDlgE:update()
         oDlgE:MySetFocus( 9 )  //aca puedo usar la posicion del objeto en aControls
         //oDlgE:MySetFocus( oGet )   //aca puedo usar un objeto
      ENDIF
   END

RETURN